azisazka: Cara memilih sel/kisaran dengan menggunakan prosedur Visual Basic pada Excel

Microsoft menyediakan pemrogaman hanya untuk ilustrasi, tanpa garansi baik tersurat maupun tersirat. Ini mencakup, namun tidak terbatas pada, garansi yang tersirat pada keadaan yang dapat diperjualbelikan atau kesesuaian untuk tujuan tertentu. Artikel ini menganggap bahwa Anda sudah terbiasa dengan bahasa pemrogaman yang ditunjukkan dan dengan alat yang digunakan untuk membuat dan memperbaiki prosedur. Teknisi Microsoft dapat membantu menjelaskan fungsionalitas prosedur tertentu, tetapi mereka tidak akan mengubah contoh ini untuk memberikan fungsionalitas tambahan atau menyusun prosedur untuk memenuhi persyaratan khusus Anda. Contoh dalam artikel ini menggunakan metode Visual Basic yang didaftar di tabel berikut.

   Metode             Argumen
   ------------------------------------------
   Activate           tidak ada
   Cells              rowIndex, columnIndex
   Application.Goto   reference, scroll
   Offset             rowOffset, columnOffset
   Range              cell1
                      cell1, cell2
   Resize             rowSize, columnSize
   Select             tidak ada
   Sheets             index (atau sheetName)
   Workbooks          index (atau bookName)
   End                direction
   CurrentRegion      tidak ada

Contoh di dalam artikel ini menggunakan properti di tabel berikut ini.

   Properti         Penggunaan
   ---------------------------------------------------------------------
   ActiveSheet      untuk menentukan lembar aktif
   ActiveWorkbook   untuk menentukan buku kerja aktif
   Columns.Count    untuk menghitung jumlah kolom pada item tertentu
   Rows.Count       untuk menghitung jumlah baris pada item tertentu
   Pilihan        untuk mengacu kepada kisaran yang baru dipilih

1: Cara Memilih Sel pada Lembar Kerja Aktif

Untuk memilih sel D5 pada lembar kerja aktif, Anda dapat menggunakan salah satu contoh berikut:


ActiveSheet.Cells(5, 4).Select

-atau-


ActiveSheet.Range("D5").Select

2: Cara Memilih Sel pada Lembar Kerja Lain di Buku Kerja yang Sama

Untuk memilih sel E6 pada lembar kerja lain di buku kerja yang sama, Anda dapat menggunakan salah satu contoh berikut:


Application.Goto ActiveWorkbook.Sheets("Sheet2").Cells(6, 5)

   -atau-


Application.Goto (ActiveWorkbook.Sheets("Sheet2").Range("E6"))

Atau, Anda dapat mengaktifkan lembar kerja, kemudian gunakan metode 1 di atas untuk memilih sel:


Sheets("Sheet2").Activate
ActiveSheet.Cells(6, 5).Select

3: Cara Memilih Sel pada Lembar Kerja di Buku Kerja yang Lain

Untuk memilih sel F7 pada lembar kerja di buku kerja yang lain, Anda dapat menggunakan salah satu contoh berikut:


Application.Goto Workbooks("BOOK2.XLS").Sheets("Sheet1").Cells(7, 6)

-atau-


Application.Goto Workbooks("BOOK2.XLS").Sheets("Sheet1").Range("F7")

Atau, Anda dapat mengaktifkan lembar kerja, kemudian gunakan metode 1 di atas untuk memilih sel:


Workbooks("BOOK2.XLS").Sheets("Sheet1").Activate
ActiveSheet.Cells(7, 6).Select

4: Cara Memilih Kisaran Sel pada Lembar Kerja Aktif

Untuk memilih kisaran C2:D10 pada lembar kerja aktif, Anda dapat menggunakan salah satu contoh berikut:


ActiveSheet.Range(Cells(2, 3), Cells(10, 4)).Select


ActiveSheet.Range("C2:D10").Select


ActiveSheet.Range("C2", "D10").Select

5: Cara Memilih Kisaran Sel pada Lembar Kerja Lain di Buku Kerja yang Sama

Untuk memilih kisaran D3:E11 pada lembar kerja lain di buku kerja yang sama, Anda dapat menggunakan salah satu contoh berikut:


Application.Goto ActiveWorkbook.Sheets("Sheet3").Range("D3:E11")


Application.Goto ActiveWorkbook.Sheets("Sheet3").Range("D3", "E11")

Atau, Anda dapat mengaktifkan lembar kerja, kemudian gunakan metode 4 di atas untuk memilih kisaran:


Sheets("Sheet3").Activate
ActiveSheet.Range(Cells(3, 4), Cells(11, 5)).Select

6: Cara Memilih Kisaran Sel pada Lembar Kerja di Buku Kerja yang Lain

Untuk memilih kisaran E4:F12 pada lembar kerja di buku kerja yang lain, Anda dapat menggunakan salah satu contoh berikut:


Application.Goto Workbooks("BOOK2.XLS").Sheets("Sheet1").Range("E4:F12")


Application.Goto _
      Workbooks("BOOK2.XLS").Sheets("Sheet1").Range("E4", "F12")

Atau, Anda dapat mengaktifkan lembar kerja, kemudian gunakan metode 4 di atas untuk memilih kisaran:


Workbooks("BOOK2.XLS").Sheets("Sheet1").Activate
   ActiveSheet.Range(Cells(4, 5), Cells(12, 6)).Select

7: Cara Memilih Kisaran Bernama pada Lembar Kerja Aktif

Untuk memilih kisaran bernama "Uji" pada lembar kerja aktif, Anda dapat menggunakan salah satu contoh berikut:


Range("Test").Select


Application.Goto "Test"

8: Cara Memilih Kisaran Bernama pada Lembar Kerja Lain di Buku Kerja yang Sama

Untuk memilih kisaran bernama "Uji" pada lembar kerja lain di buku kerja yang sama, Anda dapat menggunakan salah satu contoh berikut:


Application.Goto Sheets("Sheet1").Range("Test")

Atau, Anda dapat mengaktifkan lembar kerja, kemudian gunakan metode 7 di atas untuk memilih kisaran bernama:


Sheets("Sheet1").Activate
Range("Test").Select

9: Cara Memilih Kisaran Bernama pada Lembar Kerja di Buku Kerja yang Lain

Untuk memilih kisaran bernama "Uji" pada lembar kerja di buku kerja yang lain, Anda dapat menggunakan salah satu contoh berikut:


Application.Goto _
   Workbooks("BOOK2.XLS").Sheets("Sheet2").Range("Test")

Atau, Anda dapat mengaktifkan lembar kerja, kemudian gunakan metode 7 di atas untuk memilih kisaran bernama:


Workbooks("BOOK2.XLS").Sheets("Sheet2").Activate
Range("Test").Select

10: Cara Memilih Sel Relatif Terhadap Sel Aktif

Untuk memilih sel yang berupa lima baris di bawah dan empat kolom ke kiri dari sel aktif, Anda dapat menggunakan contoh berikut:


ActiveCell.Offset(5, -4).Select

Untuk memilih sel yang berupa dua baris di atas dan tiga kolom ke kanan dari sel aktif, Anda dapat menggunakan contoh berikut:


ActiveCell.Offset(-2, 3).Select

Catatan Kesalahan akan terjadi jika Anda mencoba untuk memilih sel yang "di luar lembar kerja." Contoh pertama yang terlihat di atas akan menghasilkan kesalahan jika sel aktif berada di kolom A hingga D, karena memindahkan empat kolom ke kiri akan membawa sel aktif ke alamat sel yang tidak valid.

11: Cara Memilih Sel Relatif Terhadap Sel Lain (yang bukan Aktif)

Untuk memilih sel yang berupa lima baris di bawah dan empat kolom ke kiri dari sel C7, Anda dapat menggunakan contoh berikut:


ActiveSheet.Cells(7, 3).Offset(5, 4).Select


ActiveSheet.Range("C7").Offset(5, 4).Select

12: Cara Memilih Kisaran Offset Sel dari Kisaran Tertentu

Untuk memilih kisaran sel yang berukuran sama dengan kisaran bernama "Uji" tapi yang diubah empat baris ke bawah dan tiga kolom ke kanan, Anda dapat menggunakan contoh berikut:


ActiveSheet.Range("Test").Offset(4, 3).Select

Apabila kisaran bernama berada di lembar kerja lain (bukan yang aktif), aktifkan lembar kerja terlebih dahulu, kemudian pilih kisaran yang menggunakan contoh berikut:


Sheets("Sheet3").Activate
ActiveSheet.Range("Test").Offset(4, 3).Select

13: Cara Memilih Kisaran Tertentu dan Mengubah Pilihan

Untuk memilih kisaran bernama "Database" kemudian perpanjang pilihan sebesar lima baris, Anda dapat menggunakan contoh berikut:


Range("Database").Select
Selection.Resize(Selection.Rows.Count + 5, _
   Selection.Columns.Count).Select

14: Cara Memilih Kisaran Tertentu, Offset Kisaran, Kemudian Ubah Kisaran

Untuk memilih kisaran empat baris di bawah dan tiga kolom ke kanan dari baris bernama "Database" dan memasukkan dua baris dan satu kolom lebih dari kisaran bernama, Anda dapat menggunakan contoh berikut:


Range("Database").Select
Selection.Offset(4, 3).Resize(Selection.Rows.Count + 2, _
   Selection.Columns.Count + 1).Select

15: Cara Memilih Gabungan Dua Kisaran Tertentu atau Lebih

Untuk memilih gabungan (yaitu, area yang digabung) dari dua kisaran bernama "Uji" dan "Contoh," Anda dapat menggunakan contoh berikut:


Application.Union(Range("Test"), Range("Sample")).Select

Perlu diingat bahwa kedua kisaran harus berada di lembar kerja yang sama pada contoh ini untuk bekerja. Perlu diingat juga bahwa metode Gabungan tidak bekerja melewati lembar. Misalnya, baris berikut ini berfungsi baik


Set y = Application.Union(Range("Sheet1!A1:B2"), Range("Sheet1!C3:D4"))

namun baris ini


Set y = Application.Union(Range("Sheet1!A1:B2"), Range("Sheet2!C3:D4"))

menghasilkan pesan kesalahan:

Metode gabungan kelas aplikasi gagal

16: Cara Memilih Titik Potong Dua Kisaran Tertentu atau Lebih

Untuk memilih titik potong dari dua kisaran bernama "Uji" dan "Contoh," Anda dapat menggunakan contoh berikut:


Application.Intersect(Range("Test"), Range("Sample")).Select

Perlu diingat bahwa kedua kisaran harus berada di lembar kerja yang sama pada contoh ini untuk bekerja.

Contoh 17-21 dalam artikel ini mengacu kepada kumpulan data contoh berikut ini. Tiap contoh menyatakan kisaran sel dalam data contoh yang akan dipilih.

   A1: Nama    B1: Penjualan    C1: Kuantitas
   A2: a       B2: $10      C2: 5
   A3: b       B3:          C3: 10
   A4: c       B4: $10      C4: 5
   A5:         B5:          C5:
   A6: Jumlah Total   B6: $20      C6: 20

17: Cara Memilih Sel Terakhir pada Kolom Data Bersebelahan

Untuk memilih sel terakhir pada kolom yang bersebelahan, gunakan contoh berikut:


ActiveSheet.Range("a1").End(xlDown).Select

Pada saat kode ini digunakan dengan tabel contoh, sel A4 akan dipilih.

18: Cara Memilih Sel Kosong di Bagian Bawah Kolom Data Bersebelahan

Untuk memilih sel di bawah kisaran sel yang bersebelahan, gunakan contoh berikut:


ActiveSheet.Range("a1").End(xlDown).Offset(1,0).Select

Pada saat kode ini digunakan dengan tabel contoh, sel A5 akan dipilih.

19: Cara Memilih Seluruh Kisaran dari Sel yang Bersebelahan pada Kolom

Untuk memilih kisaran sel yang bersebelahan pada kolom, gunakan salah satu dari contoh berikut ini:


ActiveSheet.Range("a1", ActiveSheet.Range("a1").End(xlDown)).Select

   -atau-


ActiveSheet.Range("a1:" & ActiveSheet.Range("a1"). _
      End(xlDown).Address).Select

Pada saat kode ini digunakan dengan tabel contoh, sel A1 hingga A4 akan dipilih.

20: Cara Memilih Seluruh Kisaran dari Sel yang Tidak Bersebelahan pada Kolom

Untuk memilih kisaran sel yang tidak bersebelahan, gunakan salah satu dari contoh berikut ini:


ActiveSheet.Range("a1",ActiveSheet.Range("a65536").End(xlUp)).Select

   -atau-


ActiveSheet.Range("a1:" & ActiveSheet.Range("a65536"). _
   End(xlUp).Address).Select

Pada saat kode ini digunakan dengan tabel contoh, kode tersebut akan memilih sel A1 hingga A6.

21: Cara Memilih Kisaran Sel Persegi

Untuk memilih kisaran sel persegi di sekitar sel, gunakan metode CurrentRegion. Kisaran yang dipilih dengan metode CurrentRegion adalah area yang dikelilingi oleh kombinasi dari baris kosong dan kolom kosong. Berikut ini adalah contoh dari cara menggunakan metode CurrentRegion:


ActiveSheet.Range("a1").CurrentRegion.Select

Kode ini akan memilih sel A1 hingga C4. Contoh lain untuk memilih kisaran sel yang sama ada dalam daftar berikut:


ActiveSheet.Range("a1", _
   ActiveSheet.Range("a1").End(xlDown).End(xlToRight)).Select

   -atau-


ActiveSheet.Range("a1:" & _
   ActiveSheet.Range("a1").End(xlDown).End(xlToRight).Address).Select

Pada beberapa contoh, Anda dapat memilih sel A1 hingga C6. Dalam contoh ini, metode CurrentRegion tidak akan bekerja karena adanya baris kosong pada Kisaran 5. Contoh berikut ini akan memilih semua sel:


lastCol = ActiveSheet.Range("a1").End(xlToRight).Column
lastRow = ActiveSheet.Cells(65536, lastCol).End(xlUp).Row
ActiveSheet.Range("a1", ActiveSheet.Cells(lastRow, lastCol)).Select

    -atau-


lastCol = ActiveSheet.Range("a1").End(xlToRight).Column
lastRow = ActiveSheet.Cells(65536, lastCol).End(xlUp).Row
ActiveSheet.Range("a1:" & _
   ActiveSheet.Cells(lastRow, lastCol).Address).Select

22. Cara Memilih Banyak Kolom yang Tidak Bersebelahan dengan Panjang yang Berbeda

Untuk memilih banyak kolom yang tidak bersebelahan dengan panjang yang berbeda, gunakan tabel contoh dan contoh makro berikut ini:

   A1: 1   B1: 1   C1: 1  D1: 1
   A2: 2   B2: 2   C2: 2  D2: 2
   A3: 3   B3: 3   C3: 3  D3: 3
   A4:    B4: 4   C4: 4  D4: 4
   A5:    B5: 5   C5: 5  D5:
   A6:    B6:    C6: 6  D6:


StartRange = "A1"
EndRange = "C1"
Set a = Range(StartRange, Range(StartRange).End(xlDown))
Set b = Range(EndRange, Range(EndRange).End(xlDown))
Union(a,b).Select

Pada saat kode ini digunakan dengan tabel contoh, sel A1:A3 dan C1:C6 akan dipilih.

CATATAN TENTANG CONTOH

Properti ActiveSheet biasanya dapat dihilangkan, karena properti tersebut tersirat jika lembar tertentu tidak diberi nama. Misalnya, selain daripada
```
ActiveSheet.Range("D5").Select
      
```
Anda dapat menggunakan:
```
Range("D5").Select
      
```
Properti ActiveWorkbook biasanya juga dapat dihilangkan. Kecuali jika buku kerja khusus diberi nama, buku kerja yang aktif tidak dinyatakan secara langsung.
Saat Anda menggunakan metode Application.Goto, jika Anda ingin menggunakan dua metode Sel pada metode Kisaran ketika kisaran tertentu ada di lembar kerja lain (bukan yang aktif), Anda harus memasukkan objek Lembar setiap saat. Misalnya:
```
Application.Goto Sheets("Sheet1").Range( _
      Sheets("Sheet1").Range(Sheets("Sheet1").Cells(2, 3), _
      Sheets("Sheet1").Cells(4, 5)))
     
```
Untuk item dalam tanda petik (misalnya, kisaran bernama "Uji"), Anda juga dapat menggunakan variabel yang nilainya merupakan untaian kata. Misalnya, selain daripada
```
ActiveWorkbook.Sheets("Sheet1").Activate
      
```
Anda dapat menggunakan
```
ActiveWorkbook.Sheets(myVar).Activate
      
```
dimanan nilai myVar adalah "Sheet1".

azisazka

Saturday, November 21, 2015

Cara memilih sel/kisaran dengan menggunakan prosedur Visual Basic pada Excel